Problematische Instanzbeziehungen finden

Diese Abfragen können dazu dienen, fehlerhafte oder fragwürdige Beziehungen von GND-Instanzen untereinander aufzufinden.

Personen mit nicht tätigkeitsbezogenen Schlagworten

24-Nov-2018

Mit dieser Abfrage ermitteln wir Schlagworte, die einer Person als broaderTermGeneral oder broaderTermInstantial zugeordnet sind und nicht der Sachgruppe 9.3ab (Einzelne Berufe, Tätigkeiten, Funktionen; Religionszugehörigkeit, Weltanschauung) angehören.

In der ersten Form erhalten wir die Liste der Schlagworte nach absteigender Häufigkeit geordnet:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX gndsc: <http://d-nb.info/standards/vocab/gnd/gnd-sc#>

select (count(?schlagwortId) as ?anz) ?schlagwort where 
{
  ?personId a gndo:DifferentiatedPerson .
  ?personId gndo:broaderTermGeneral ?schlagwortId .
# ?personId gndo:broaderTermInstantial ?schlagwortId .
  ?schlagwortId gndo:preferredNameForTheSubjectHeading ?schlagwort .
  MINUS { ?schlagwortId gndo:gndSubjectCategory gndsc:9.4ab }
}
GROUP BY ?schlagwortId ?schlagwort ORDER BY DESC(?anz)

In der zweiten Form werden alle betreffenden Personen mit ausgegeben:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX gndsc: <http://d-nb.info/standards/vocab/gnd/gnd-sc#>

select ?personId ?person ?schlagwortId ?schlagwort where 
{
  ?personId a gndo:DifferentiatedPerson .
  ?personId gndo:broaderTermGeneral ?schlagwortId .
# ?personId gndo:broaderTermInstantial ?schlagwortId .
  ?schlagwortId gndo:preferredNameForTheSubjectHeading ?schlagwort .
  ?personId gndo:preferredNameForThePerson ?person .
  MINUS { ?schlagwortId gndo:gndSubjectCategory gndsc:9.4ab }
}

Instanzbeziehungen zwischen Allgemeinbegriffen

26-Nov-2018

Instanzen sind der Definition nach Individuen und damit keine Allgemeinbegriffe. Mit dieser Abfrage lassen sich Beispiele für einen fehlerhaften Gebrauch der Property gndo:broaderTermInstantial finden.

PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX gnd: <http://d-nb.info/gnd/>

select ?nt ?ntname ?bt ?btname where
{
  ?nt a gndo:SubjectHeadingSensoStricto ;
  	gndo:broaderTermInstantial ?bt ;
    gndo:preferredNameForTheSubjectHeading ?ntname .
  ?bt a gndo:SubjectHeadingSensoStricto ;
  	gndo:preferredNameForTheSubjectHeading ?btname
}

5.621 Vorkommen im GND-Bestand von August 2019; 7.328 Vorkommen im GND-Bestand von Februar 2020.

Werke als Instanzen von Individualbegriffen

Eine Instanzbeziehung von einem Werk zu einem Individualbegriff sollte nicht vorkommen. Hiermit kann eine Liste solcher Fälle erhalten werden:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 
select ?werk ?wid ?wclass ?bterm ?btid ?btclass where
{
  ?prefName rdfs:subPropertyOf gndo:preferredName .
  { ?wid a [ rdfs:subClassOf gndo:Work ] } UNION  { ?wid a gndo:Work }
  ?wid a ?wclass ;
       gndo:broaderTermInstantial ?btid ;
       gndo:preferredNameForTheWork ?werk .
  ?btid a ?btclass ;
       ?prefName ?bterm .
  FILTER NOT EXISTS { ?btid a gndo:SubjectHeadingSensoStricto }
  FILTER NOT EXISTS { ?btid a gndo:SubjectHeading }
}

90 Vorkommen im GND-Bestand von August 2019; 170 Vorkommen im GND-Bestand von Februar 2020.

Desgleichen für Bauwerke (diese sind keine Unterklasse von gndo:Werk, deshalb wird eine separate Abfrage benötigt):

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 
select ?bauwerk ?bwid ?term ?bt ?btclass where
{
  ?prefName rdfs:subPropertyOf gndo:preferredName .
  ?bwid a gndo:BuildingOrMemorial ;
       gndo:broaderTermInstantial ?bt ;
       gndo:preferredNameForThePlaceOrGeographicName ?bauwerk .
  ?bt a ?btclass ;
       ?prefName ?term .
  FILTER NOT EXISTS { ?bt a gndo:SubjectHeadingSensoStricto }
  FILTER NOT EXISTS { ?bt a gndo:SubjectHeading }
}

15 Vorkommen im GND-Bestand von September 2019; 21 Vorkommen im GND-Bestand von Februar 2020