Architekten, die keine sind

Nicht alle Personen, die mittels gndo:architect einem Bauwerk zugeordnet sind, haben "Architekt" als Berufsangabe. Welche das sind, lässt sich mit dieser Abfrage ermitteln:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>

SELECT * WHERE
{
  ?bauwerkId gndo:architect ?akteurId .
  ?akteurId a gndo:DifferentiatedPerson .
  ?akteurId gndo:preferredNameForThePerson ?akteur .
  ?bauwerkId gndo:preferredNameForThePlaceOrGeographicName ?bauwerk .
  ?akteurId gndo:professionOrOccupation [ gndo:preferredNameForTheSubjectHeading ?beruf ]
  FILTER NOT EXISTS { ?akteurId gndo:professionOrOccupation gnd:4002844-6 }
}

Kurzlebige Bauwerke

Angaben aus MARC21 548 $4 datb (Zeit des Bestehens) werden in der Linked-Data-Darstellung in ein Zeitintervall mit den Properties gndo:dateOfEstablishment und gndo:dateOfTermination gewandelt. Bei Bauwerken scheint es sich hierbei aber häufig um die Zeitspanne der Errichtung (MARC21 548 $4 dats) zu handeln. Verdachtsfälle lassen sich mit dieser Abfrage finden:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 
#getestet: 23-Jan-2019
SELECT * WHERE
{
  ?s a gndo:BuildingOrMemorial ;
     gndo:preferredNameForThePlaceOrGeographicName ?bwname ;
     gndo:dateOfEstablishment ?de ;
     gndo:dateOfTermination ?dt .
  FILTER (STRDT(?dt, xsd:integer) - STRDT(?de, xsd:integer) < 10 )
}

Hier wandeln wir die Jahresangaben in ganze Zahlen und filtern jene Bauwerke heraus, bei denen die Differenz zwischen Errichtung und Abriss weniger als 10 Jahre beträgt.

Unnatürliche Entitäten mit Geburtsdatum

Die Angabe eines Geburtsdatums ist in der GNDO nicht nur für die Klasse DifferentiatedPerson, sondern auch für alle Unterklassen hiervon definiert. Zu den Unterklassen zählen u.a. Sagengestalten, Götter und Geister, sowie Kolletivpseudonyme. Unter der Annahme, dass es sich nur bei den Klassen DifferentiatedPerson und RoyalOrMemberOfARoyalHouse um natürliche Personen handelt, können wir problematische Klassenzuordnungen mit der folgenden Abfrage finden:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT * WHERE
{
  ?s gndo:dateOfBirth ?d ;
     a ?gndoclass .
  FILTER NOT EXISTS { ?s a gndo:DifferentiatedPerson } .
  FILTER NOT EXISTS { ?s a gndo:RoyalOrMemberOfARoyalHouse }
}

Browser nicht unterstützt