Konformitäts-Verstöße

Verstöße gegen Axiome der GND-Ontologie auffinden.

Verstöße gegen Domain-Restriktion für eine GNDO-Property finden

21-Sep-2018

Am Beispiel gndo:manufacturer zeigen sich deutliche Diskrepanzen zwischen den nach der GNDO zulässigen Klassen und den tatsächlich vorkommenden Aussagen.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

# Verstöße gegen Domain-Restriktion für eine GNDO-Property finden
#
# Ermittelt werden die zulässigen Domain-Klassen für gndo:manufacturer.
# Aus allen Instanzen dieser Property werden jene mit zulässiger
# Domain-Klasse entfernt.
# Für jede der als Domain unzulässigen Klassen wird die Anzahl der 
# Instanzen ermittelt.
# 
SELECT ?domInstance (count(?domInstance) as ?n)
{
  BIND ( gndo:manufacturer AS ?testprop )
  ?testprop rdfs:domain [ owl:unionOf [ rdf:rest*/rdf:first ?domClass ]] .
  ?s ?testprop ?o .
  ?s a ?domInstance .
  FILTER NOT EXISTS { ?s a ?domClass } .
}
GROUP BY ?domInstance 

Nicht alle hier gefundenen Fälle deuten auf unplausible Aussagen hin. Wird die Anfrage (durch Ändern der Zeile 10) auf gndo:formerOwner angewandt, finden wir häufige Verwendungen für Manuskripte und Bauwerke; beides Dinge, die durchaus einen Vorbesitzer haben können, aber aufgrund der Domain-Restriktion hier nicht zulässig sind.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

# Verstöße gegen Domain-Restriktion für eine GNDO-Property finden 
#
SELECT ?domInstance (count(?domInstance) as ?n)
{
  BIND ( gndo:manufacturer AS ?testprop )
  ?testprop rdfs:domain [ owl:unionOf [ rdf:rest*/rdf:first ?domClass ]] . 
  ?s ?testprop ?o .
  ?s a ?domInstance .
  FILTER NOT EXISTS { ?s a ?domClass } .
}
GROUP BY ?domInstance

Nicht-konforme Pseudonymbeziehungen

29-Nov-2018

Zu 8.011 Aussagen mit der Property gndo:pseudonym gibt es in 5.859 Fällen eine GNDO-konforme Umkehrbeziehung mit gndo:realIdentity.

Bei den 2.133 verbleibenden Fällen handelt es sich 1.976 mal um einen nicht-konformen Gebrauch der Pseudonymbeziehung in der Form A gndo:pseudonym B gndo:pseudonym A, d.h. eine Verwendung der Property als symmetrische Beziehung. Diese Form wird in der GND verwendet, um Beziehungen pseudonymer Identitäten untereinander auszudrücken:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>

# Reflexiver Gebrauch der Property gndo:pseudonym
SELECT * WHERE 
{
  ?s gndo:pseudonym ?o ;
     gndo:preferredNameForThePerson ?sname .
  ?o gndo:pseudonym ?s ;
     gndo:preferredNameForThePerson ?oname .
}

Diese Verwendung von gndo:pseudonym führt dazu, dass sämtliche Beziehungen zwischen einer realen Identität und ihren Pseudonymen sowie den Pseudonymen untereinander in der GND ausgedrückt werden. In folgendem Beispiel können alle 16 (grünen) Instanzen von gndo:pseudonym als redundant angesehen werden, da sie sich per Inferenz aus den vier (roten) Instanzen von gndo:realIdentity herleiten lassen:

Nach Ausschluss der korrekten und der symmetrischen Pseudonymbeziehungen verbleiben 129 Fälle, in denen die Property gndo:pseudonym weder GNDO-konform noch symmetrisch angewandt wird. Hierbei fehlt stets der Rückverweis zum Aussagesubjekt:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gnd: <http://d-nb.info/gnd/>
PREFIX gndo: <http://d-nb.info/standards/elementset/gnd#>

# Pseudonymbeziehungen ohne Rückverweis
SELECT * WHERE
{
	?s gndo:pseudonym ?o .
	?s gndo:preferredNameForThePerson ?sname .
	?o gndo:preferredNameForThePerson ?oname .
	MINUS { ?s gndo:pseudonym [ gndo:realIdentity ?s ] }
  	MINUS { ?s gndo:pseudonym [ gndo:pseudonym ?s ] }
}

Einige dieser Fälle gehen darauf zurück, dass die Umkehrbeziehung durch keine der beiden Pseudonymbeziehungen, sondern als unspezifische Personenbeziehung (MARC21: 500 $0 $4=rela) ausgedrückt und diese außerdem nicht in die Linked Data-Repräsentation übernommen wird. In anderen Fällen wird die Beziehung von einem Sammelpseudonym zu den realen Personen nicht in die Linked Data-Repräsentation übernommen, obwohl in MARC21 als 500 $0 $4=nawi angegeben. In anderen Fällen wie http://d-nb.info/gnd/121057313 erscheint der wirkliche Name unter 500 $0 $4=bezb und wird damit zu gndo:professionalRelationship.